Hacktoberfest 2026: le issue che i maintainer hanno segnato per ottobre, aperte e adatte ai principianti. Sfoglia le issue Hacktoberfest

Skip the `FSharpType.IsUnion` check when a quotation node for an instance member is built

Aperta
  • Qualcosa non va?
#20,765 1 commento 0 reazioni 0 assegnatari Vedi su GitHub

I maintainer di solito rispondono entro 3 giorni

Nessuno ha ancora preso questa issue.

Valutazione

Difficoltà
3/5
Tempo stimato
1-2 giorni
Idoneità per principianti
57/100
Tipo di issue
Funzionalità
Chiarezza
Abbastanza chiara
Stato di attività
Attiva
Stack tecnologico
fsharp
Ambito
performance

Direzione di ricerca

Start by reading checkObj and the instance member builders named in the issue, then inspect how RebuildShapeCombination reaches them. The proposed change is to check whether the receiver type is assignable to the declaring type before running the union type lookup. Verify that existing accepted and rejected receiver cases remain the same and compare instance member construction benchmarks with the static case.

Scritto dal modello di indicizzazione a partire dal testo della issue.

Descrizione

Feature Request

Is your feature request related to a problem? Please describe.

Building a quotation node for an instance property, field or method takes 5 µs, a hundred times what the node for a static member takes. Every transformation through ExprShape pays that for each such node, because RebuildShapeCombination runs the same check as Expr.PropertyGet and Expr.Call.

type Person = { Name : string; Age : int; City : string }
type Clock () =
    static member Zone = "UTC"

[<MemoryDiagnoser>]
type InstanceMember () =
    let p = Var ("p", typeof<Person>)
    let q = Var ("q", typeof<Person>)
    let person = Expr.Var p
    let age = typeof<Person>.GetProperty "Age"
    let zone = typeof<Clock>.GetProperty "Zone"
    let predicate =
        <@@ (%%person : Person).Age >= 18 && (%%person : Person).City = "Kyiv" && (%%person : Person).Name <> "" @@>

    let rec renameByShape (expr : Expr) : Expr =
        match expr with
        | ShapeVar v -> if v = p then Expr.Var q else expr
        | ShapeLambda (v, body) -> Expr.Lambda (v, renameByShape body)
        | ShapeCombination (shape, parts) -> RebuildShapeCombination (shape, List.map renameByShape parts)

    [<Benchmark>]
    member _.StaticProperty () = Expr.PropertyGet zone
    [<Benchmark>]
    member _.InstanceProperty () = Expr.PropertyGet (person, age)
    [<Benchmark>]
    member _.IsUnion () = FSharpType.IsUnion typeof<Person>
    [<Benchmark>]
    member _.RenameByShape () = renameByShape predicate
    [<Benchmark>]
    member _.RenameBySubstitute () = predicate.Substitute (fun v -> if v = p then Some (Expr.Var q) else None)
Method Mean Allocated
StaticProperty 0.05 µs 104 B
InstanceProperty 5.2 µs 1216 B
IsUnion 5.1 µs 1080 B
RenameByShape 20.1 µs 7824 B
RenameBySubstitute 0.8 µs 2264 B

BenchmarkDotNet 0.15.8, .NET 10.0.12, FSharp.Core 10.1.401, Windows 11 x64. The machine was not idle: standard deviations are up to 10 percent, the allocations are exact. A property of a class, an instance method call and RebuildShapeCombination of one such node measure like InstanceProperty.

Where it goes, as far as I read the code at a274432:

  • mkInstancePropGet, mkInstancePropSet, mkInstanceFieldGet, mkInstanceFieldSet, mkInstanceMethodCall and mkInstanceMethodCallW call checkObj, and RebuildShapeCombination calls them.

  • checkObj first asks FSharpType.IsUnion about the declaring type, for the case that the member belongs to the nested class of a union case:

    let rec loop (ty: Type) =
    if FSharpType.IsUnion ty && FSharpType.IsUnion ty.BaseType then loop ty.BaseType else ty

let declType = loop membInfo.DeclaringType

if not (assignableFrom declType (typeOf obj)) then
    invalidArg "obj" (SR.GetString(SR.QincorrectInstanceType))

  • FSharpType.IsUnion reads CompilationMappingAttribute through GetCustomAttributes and keeps nothing; for a record type that is four reads in one call (isExceptionRepr, isConstructorRepr for the type and its base type, isUnionType).

  • Expr.Substitute builds nodes without the check, hence the last row.

Describe the solution you'd like

Test the common case first: when the receiver's type is assignable to the declaring type, the node is valid and nothing else has to be asked.

let checkObj (membInfo: MemberInfo) (obj: Expr) =
    let objType = typeOf obj

    if not (assignableFrom membInfo.DeclaringType objType) then
        // as today: find the union type, test again, raise

It accepts and rejects what the current code does: loop gives the declaring type or a base type of it, and a receiver assignable to a type is assignable to its base types. I have not built FSharp.Core with it; from the table, an instance member node should then cost about what a static one costs. I can send a pull request.

Describe alternatives you've considered

  • Keeping the answer of FSharpType.IsUnion per type. It helps every caller of FSharp.Reflection, but adds a cache for the life of the process where the change above removes the question.
  • In my code: Expr.Substitute where a rewrite only replaces variables. A rewrite that replaces any other node still rebuilds every node above it.

Additional context

Found while measuring a quotation normalizer (pipes, let and [<ReflectedDefinition>] calls rewritten away) for fsprojects/FSharp.Azure.Cosmos: inlining a function with five member accesses took about 57 µs through ExprShape and 22 µs once the parameters were replaced with Expr.Substitute.

Lingua principale
F#
Stelle
4.3k
Fork
880
Merge medio
3g 21h
PR unite (30g)
109

Preparare l'ambiente

Apri in Codespaces

Avvia il container di sviluppo del progetto nel browser, con il tuo account GitHub.

Come iniziare

  1. Leggi tutta la issue e poi la guida ai contributi del progetto.
  2. Commenta sulla issue per dire che te ne occupi tu — evita che due persone facciano lo stesso lavoro.
  3. Fai un fork del repository e lavora su un branch.
  4. Apri una pull request che faccia riferimento al numero della issue.

Altre issue di dotnet/fsharp

Tutte le issue di dotnet/fsharp

Issue simili

Altre issue su Performance

Ricevi le nuove issue nella tua casella

Un breve riepilogo di issue GitHub adatte ai principianti.