Grammar railroad diagram
Los mantenedores suelen responder en 1 día
Nadie ha tomado este issue todavía.
Evaluación
- Dificultad
- 3/5
- Tiempo estimado
- 1-2 días
- Aptitud para principiantes
- 35/100
- Tipo de issue
- Documentación
- Claridad
- Necesita aclaración
- Estado de actividad
- Estancado
- Stack tecnológico
- javascript
- Área
- documentation
Línea de trabajo
Comienza con dbml/parser.pegjs y compara su gramática con la EBNF proporcionada; después, pega la EBNF en BottleCaps Railroad Diagram Generator para inspeccionar el resultado. El issue no identifica ningún archivo del repositorio ni ningún entregable solicitado; para completarlo harían falta una ubicación acordada y un diagrama renderizado que represente la gramática con precisión.
Escrito por el modelo de indexación a partir del texto del issue.
Descripción
Using a custom parser that translates dbml/parser.pegjs grammar to an EBNF understood by https://www.bottlecaps.de/rr/ui and manually fixing small errors we can have nice railroad diagram (https://en.wikipedia.org/wiki/Syntax_diagram) to help show/understand the syntax.
Copy and paste the EBNF shown bellow at https://www.bottlecaps.de/rr/ui on the tab Edit Grammar then click on the tab View Diagram.
//To be viewd at https://www.bottlecaps.de/rr/ui
rules ::=
expr*
expr ::=
TableSyntax
| RefSyntax
| EnumSyntax
| TableGroupSyntax
| ProjectSyntax
| __
TableSyntax ::=
table sp+ schema_name? name alias_def? sp* TableSettings? _ "{" TableBody "}"
RefSyntax ::=
ref_long
| ref_short
EnumSyntax ::=
enum sp+ schema_name? name _ "{" EnumBody "}"
TableGroupSyntax ::=
table_group sp+ schema_name? name _ "{" _ table_group_body _ "}"
ProjectSyntax ::=
project ( __ name )? _ "{" _ ProjectBody _ "}"
__ ::=
( comment | whitespace )+
project ::=
"project"
name ::=
character+
| ( quote [^\"\n]+ quote )
_ ::=
( comment | whitespace )*
ProjectBody ::=
_ ProjectElement* _
ProjectElement ::=
( _ ObjectNoteElement _ )
| ( _ TableSyntax _ )
| ( _ RefSyntax _ )
| ( _ EnumSyntax _ )
| ( TableGroupSyntax _ )
| ( _ ProjectField _ )
ObjectNoteElement ::=
ObjectNote
| ( "note" _ "{" _ StringLiteral _ "}" )
ProjectField ::=
name _ ":" _ StringLiteral
StringLiteral ::=
( '"' DoubleStringCharacter* '"' )
| ( "'''" MultiLineStringCharacter* "'''" )
| ( "'" SingleStringCharacter* "'" )
table_group ::=
"TableGroup"
sp ::=
" "
schema_name ::=
name "."
table_group_body ::=
( schema_name? name __ )*
ref_long ::=
ref ( __ name )? _ "{" _ ref_body _ "}"
ref_short ::=
ref ( sp+ name )? sp* ":" sp* ref_body
ref ::=
"ref"
ref_body ::=
field_identifier sp+ relation sp+ field_identifier sp* RefSettings?
field_identifier ::=
( name "." name "." RefField )
| ( name "." RefField )
relation ::=
[>-<]
RefSettings ::=
"[" RefSetting ( Comma RefSetting )* "]"
RefField ::=
RefSingleField
| RefMultipleFields
RefSingleField ::=
name
RefMultipleFields ::=
"(" sp* RefSingleField ( sp* Comma sp* RefSingleField )* sp* ")"
Comma ::=
","
RefSetting ::=
( _ OnUpdate _ )
| ( _ OnDelete _ )
OnUpdate ::=
"update:" _ ( no_action | restrict | cascade | set_null | set_default )
OnDelete ::=
"delete:" _ ( no_action | restrict | cascade | set_null | set_default )
no_action ::=
"no action"
restrict ::=
"restrict"
cascade ::=
"cascade"
set_null ::=
"set null"
set_default ::=
"set default"
table ::=
"table"
alias_def ::=
sp+ "as" sp+ name
TableSettings ::=
"[" TableSetting ( Comma TableSetting )* "]"
TableBody ::=
_ Field+ _ TableElement* _
Field ::=
_ name sp+ schema_name? type ( sp+ constrain )* ( sp+ FieldSettings )? sp* comment? newline
TableElement ::=
( _ Indexes _ )
| ( _ ObjectNoteElement _ )
Indexes ::=
_ indexes _ "{" IndexesBody "}"
type ::=
type_name ( sp* "(" sp* expression sp* ")" )?
constrain ::=
unique
| pk
FieldSettings ::=
"[" FieldSetting ( Comma FieldSetting )* "]"
comment ::=
single_line_comment
| multi_lime_comment
newline ::=
"\r\n"
| "\n"
enum ::=
"enum"
EnumBody ::=
_ EnumValue+ _
EnumValue ::=
_ name sp* EnumSetting? sp* comment? newline
EnumSetting ::=
"[" _ ObjectNote _ "]"
ObjectNote ::=
"note:" _ StringLiteral
FieldSetting ::=
( _ "not null" _ )
| ( _ "null" _ )
| ( _ "primary key" _ )
| ( _ "pk" _ )
| ( _ "unique" _ )
| ( _ "increment" _ )
| ( _ ObjectNote _ )
| ( _ RefInline _ )
| ( _ Default _ )
TableSetting ::=
( _ ObjectNote _ )
| ( _ HeaderColor _ )
HeaderColor ::=
_ header_color ":" _ sharp hex_color _
RefInline ::=
"ref:" sp* relation sp+ inline_field_identifier
Default ::=
"default:" _ DefaultVal
indexes ::=
"indexes"
IndexesBody ::=
_ Index+ _
Index ::=
_ ( SingleIndexSyntax | CompositeIndexSyntax ) _
SingleIndexSyntax ::=
_ SingleIndex sp* IndexSettings?
CompositeIndexSyntax ::=
_ CompositeIndex sp* IndexSettings?
SingleIndex ::=
( name sp* )
| Expression
IndexSettings ::=
( "[" sp* pk sp* "]" )
| ( "[" IndexSetting ( Comma IndexSetting )* "]" )
CompositeIndex ::=
"(" sp* SingleIndex ( Comma sp* SingleIndex )* ")"
Expression ::=
"`" [^`]* "`"
pk ::=
"pk"
IndexSetting ::=
( _ "unique" _ )
| ( _ IndexName _ )
| ( _ IndexType _ )
| ( _ ObjectNote _ )
IndexName ::=
"name:" _ StringLiteral
IndexType ::=
"type:" _ ( btree | hash )
btree ::=
"btree"
hash ::=
"hash"
inline_field_identifier ::=
( name "." name "." name )
| ( name "." name )
DefaultVal ::=
StringLiteral
| Expression
| BooleanLiteral
| NumberLiteral
BooleanLiteral ::=
'true'
| 'false'
| 'null'
NumberLiteral ::=
"-"? ( float | integer )
header_color ::=
"headercolor"
sharp ::=
"#"
hex_color ::=
six_char
| three_char
six_char ::=
hex_char hex_char hex_char hex_char hex_char hex_char
three_char ::=
hex_char hex_char hex_char
hex_char ::=
[0-9a-fA-F]
unique ::=
"unique"
as ::=
"as"
character ::=
[a-zA-Z0-9_]
quote ::=
'"'
type_name ::=
type_character+
| ( quote [^\"\n]+ quote )
type_character ::=
character
| [#x5B#x5D]
expression ::=
factor*
factor ::=
( character+ sp* "(" expression ")" )
| ( "(" expression ")" )
| ( exprCharNoCommaSpace+ ( sp* | "," | ");" | ( endline ");" ) ) )
| ( exprChar+ . )
exprCharNoCommaSpace ::=
[\'.a-zA-Z0-9_+-]
endline ::=
sp* newline
exprChar ::=
[\',.a-zA-Z0-9_+-`]
| sp
| newline
| tab
tab ::=
"\t"
allowed_chars ::=
_NOT_ ( '{' | '}' | whitespace_quote ) .
whitespace_quote ::=
[ \t\r\n\r\"]
whitespace ::=
[ \t\r\n\r]
single_line_comment ::=
"//" [^\n]*
multi_lime_comment ::=
"/*" ( _NOT_ "*/" . )* "*/"
DoubleStringCharacter ::=
( '\\' '"' )
| ( _NOT_ '"' SourceCharacter )
MultiLineStringCharacter ::=
"\\'"
| ( "\\" "\\"+ )
| ( "\\" "\n"? )
| ( _NOT_ "'''" SourceCharacter )
SingleStringCharacter ::=
"\\'"
| ( _NOT_ "'" SourceCharacter )
SourceCharacter ::=
.
digit ::=
[0-9]
decimal_point ::=
dot
dot ::=
'.'
equal ::=
'='
float ::=
[0-9]+ "." [0-9]+
integer ::=
[0-9]+
//Added tokens for railroad generation
_NOT_ ::= '!'
_AND_ ::= '&'
- Lenguaje dominante
- JavaScript
- Estrellas
- 3.7k
- Forks
- 233
- Merge medio
- 2 d 4 h
- PR fusionados (30 d)
- 23
Preparar el entorno
Primeros pasos
- Lee el issue completo y luego la guía de contribución del proyecto.
- Comenta en el issue que vas a ocuparte — evita que dos personas hagan lo mismo.
- Haz un fork del repositorio y trabaja en una rama.
- Abre un pull request que haga referencia al número del issue.
Más de holistics/dbml
-
Dificultad 2/5 1-3 horas Aptitud para principiantes 78/100
Los mantenedores suelen responder en 1 día
-
@dbml/core 12.0.0 Postgres importer: timestamptz becomes timestamp, schema-qualified type doubled, Ref with ?<? rejected by parserPosiblemente ocupada @zzoraemon043 la tomó hace 2 días. Abierto
Dificultad 3/5 1-2 días Aptitud para principiantes 68/100
Los mantenedores suelen responder en 1 día
-
Dificultad 5/5 Más de una semana Aptitud para principiantes 38/100
holistics/dbml#884 · 3 comentarios ·
Los mantenedores suelen responder en 1 día
-
Dificultad 3/5 1-2 días Aptitud para principiantes 48/100
holistics/dbml#880 · 3 comentarios ·
Los mantenedores suelen responder en 1 día
-
enhancement
Dificultad 5/5 Más de una semana Aptitud para principiantes 35/100
holistics/dbml#868 · 1 comentario · 1 reacción ·
Los mantenedores suelen responder en 1 día
Todos los issues de holistics/dbml
Issues similares
-
Dificultad 2/5 1-3 horas Aptitud para principiantes 78/100
-
bug
Dificultad 2/5 1-3 horas Aptitud para principiantes 68/100
mailcow/mailcow-dockerized#7677 · 1 comentario ·
Los mantenedores suelen responder en 1 día
-
Dificultad 2/5 1-3 horas Aptitud para principiantes 72/100
gcivil-nyu-org/team5-mon-fall26#145 ·
Los mantenedores suelen responder en 1 día
-
Dificultad 2/5 1-3 horas Aptitud para principiantes 82/100
-
needs discussion
Dificultad 2/5 1-3 horas Aptitud para principiantes 78/100
openfga/openfga.dev#1436 · 1 comentario ·
Los mantenedores suelen responder en 2 días